tomox2さん、こんにちは。

EnumPrintersを使うのにコールバック関数は必要ないはずです。
以下は、使用できるプリンタ名の一覧を取得する方法です。

構造体
PRINTER_INFO_5
　UnsignedLong pPrinterName
　UnsignedLong pPortName
　UnsignedLong Attributes
　UnsignedLong DeviceNotSelectedTimeout
　UnsignedLong TransmissionRetryTimeout

外部関数
FUNCTION Boolean EnumPrinters(UnsignedLong Flags, UnsignedLong Name,&
　　　　UnsignedLong Level, REF Blob pPrinterEnum,UnsignedLong cbBuf,&
　　　　REF UnsignedLong pcbNeeded, REF UnsignedLong pcReturned)&
　　　　LIBRARY \"WINSPOOL.DRV\" ALIAS FOR \"EnumPrintersA\"
SUBROUTINE MemMove(REF Structure dst[],REF Blob src,Long len)&
　　　　LIBRARY \"KERNEL32.DLL\" ALIAS FOR \"RtlMoveMemory\"

スクリプト
//定数宣言
CONSTANT UnsignedLong PRINTER_ENUM_LOCAL = 2

//変数宣言
String PrinterList[]
Blob PrinterInfoBlob
PRINTER_INFO_5 PrinterInfo[], PrinterInfoDefault
Boolean ret
UnsignedLong cbNeeded, cReturned, p

//必要な領域サイズ取得
ret = EnumPrinters(PRINTER_ENUM_LOCAL, 0, 5, PrinterInfoBlob, 0, cbNeeded, cReturned)
IF cbNeeded > 0 THEN
　　//領域確保
　　PrinterInfoBlob = Blob(Space(cbNeeded))
　　//プリンタ情報を取得
　　ret = EnumPrinters(PRINTER_ENUM_LOCAL, 0, 5, PrinterInfoBlob, cbNeeded, cbNeeded, cReturned)
END IF
IF ret AND cReturned > 0 THEN
　　//構造体配列にコピー
　　PrinterInfo[cReturned] = PrinterInfoDefault
　　MemMove(PrinterInfo, PrinterInfoBlob, 20 * cReturned) //20は構造体のサイズ
　　//プリンタ名を取得
　　FOR p = 1 TO cReturned
　　　　PrinterList[p] = String(PrinterInfo[p].pPrinterName, \"address\")
　　NEXT
ELSE
　　//取得できない
END IF

※WinNT/2000では、Level=4(PRINTER_INFO_4)の方が速いらしいです。
　PRINTER_INFO_4構造体の内容は、winspool.hを参照してください。
　ただし、Win9xではLevel=4は使えません。